/*
File: 	17th_pums_person.do
Date:	Feb 14, 2004
Desc:	Creates a consistent set of selected person-level variables from 
	the 1990 and 2000 Decennial Census PUMS 1%
*/

/* Determine data year */

local year=`1' /* get data year from 17th_pums_master.do */

/* relationship to householder */

gen byte reltohh=.

if `year'==1980 {
replace reltohh=1 if relat1==0 /* householder */
replace reltohh=2 if relat1==1 /* spouse */
replace reltohh=3 if relat1==2 /* child */
replace reltohh=4 if 3<=relat1 & relat1<=5 /* other relative */
replace reltohh=5 if 6<=relat1 & relat1<=11 /* not related */
}
if `year'==1990 {
replace reltohh=1 if relat1==0 /* householder */
replace reltohh=2 if relat1==1 /* spouse */
replace reltohh=2 if relat1==10 /* unmarried partner */
replace reltohh=3 if relat1==2 | relat1==3 /* child */
replace reltohh=4 if 4<=relat1 & relat1<=7 /* other relative */
replace reltohh=5 if relat1==8 | relat1==9 | (11<=relat1 & relat1<=13)
/* not related, including foster child */
}
if `year'==2000 {
replace reltohh=1 if relate==1 /* householder */
replace reltohh=2 if relate==2 /* spouse */
replace reltohh=2 if relate==19 /* unmarried partner */
replace reltohh=3 if 3<=relate & relate<=5 /* child */
replace reltohh=4 if 6<=relate & relate<=16 /* other relative */
replace reltohh=5 if relate==17 | relate==18 | relate==20
/* not related, including foster children */
}
lab var reltohh "Relationship to householder"
#delimit ;
lab def reltohh
1 "Householder"
2 "Spouse, unmarried partner"
3 "Related child"
4 "Other relative"
5 "Not related";
#delimit cr
lab val reltohh reltohh

/* sub-family */

gen subfamn=.

if `year'==1980 {
replace subfamn=subfam2
}
if `year'==1990 {
replace subfamn=subfam2
}
if `year'==2000 {
replace subfamn=sfn
}
lab var subfamn "Subfamily number"
notes subfamn: Zero indicates not a member of a subfamily

/* age */

if `year'==1980 {
*use variable age /* top-coded at 90 */
}
if `year'==1990 {
*use variable age /* top-coded at 90 */
}
if `year'==2000 {
replace age=90 if 90<age & age~=. /* for consistency with 1990, 2000 */
}
lab var age "Age"
notes age: Top-code is 90

/* gender */

gen byte female=.

if `year'==1980 | `year'==1990 {
replace female=0 if sex==0
replace female=1 if sex==1
}
if `year'==2000 {
replace female=0 if sex==1
replace female=1 if sex==2
}
lab var female "Female"

/* race and ethnicity 

	NOTE: major recode of race variable in 2000 
	
*/

	/* wbho */
	
gen byte wbho=. /* available 1990, 2000 */

if `year'==1980 {
replace wbho=1 if race==1 /* white */
replace wbho=2 if race==2 /* black */
replace wbho=4 if 3<=race & race<=13 /* other */
replace wbho=3 if 1<=spanish & spanish<=4 /* spanish origin */
}
if `year'==1990 {
replace wbho=1 if race==1 /* white */
replace wbho=2 if race==2 /* black */
replace wbho=4 if 3<=race & race<=327 
/* american indian, aleut eskimo; asian or pacific island; other */
replace wbho=3 if 1<=hispanic & hispanic<=3 
/* mexican, puerto rican, Cuban */
replace wbho=3 if 200<=hispanic & hispanic<=299
/* hispanic categories including Spain */
}
if `year'==2000 {
* white
replace wbho=1 if race3==47 /* white alone */
* black
replace wbho=2 if race3==37 /* black or african american alone */
replace wbho=2 if race3==68 /* white and black or african american */
replace wbho=2 if race3==69 | race3==70 /* white and black and other */
replace wbho=2 if 38<=race3 & race3<=46 /* black and other */
* other
replace wbho=4 if 3<=race1 & race1<=8 /* other alone */
replace wbho=4 if 48<=race3 & race3<=67 /* white and other */
replace wbho=4 if race3==71 /* all other combinations */
* hispanic
replace wbho=3 if 2<=hispan & hispan<=24 /* hispanic including Spain */
}
lab var wbho "Race"
#delimit ;
lab define wbho
1 "White"
2 "Black"
3 "Hispanic"
4 "Other";
#delimit cr
lab val wbho wbho
notes wbho: Racial and ethnic categories are mutually exclusive
notes wbho: Major recoding of Census race variable in 2000
notes wbho: From 2000, black includes all respondents listing black; other /*
*/ includes all respondents listing non-white or non-black races, except /*
*/ those also listing black

	/* wbhom */
	
gen byte wbhom=.

if `year'==1980 | `year'==1990 {
* wbhom not available
}
if `year'==2000 {
replace wbhom=1 if race1==1 /* white alone */
replace wbhom=2 if race1==2 /* black or african american alone */
replace wbhom=4 if 3<=race1 & race1<=8 /* other race alone */
replace wbhom=5 if race1==9 /* two or more major race groups */
replace wbhom=3 if 2<=hispan & hispan<=24 /* hispanic including Spain */
}
lab var wbhom "Race, inc. mixed"
#delimit ;
lab define wbhom
1 "White"
2 "Black"
3 "Hispanic"
4 "Other"
5 "Mixed";
#delimit cr
lab val wbhom wbhom
notes wbhom: Racial and ethnic categories are mutually exclusive
notes wbhom: Major recoding of race variable in 2000
notes wbhom: From 2000, black, white, and other exclude all respondents /*
*/ listing more than one race (except mixes of AI, Asian, and HP, which /*
*/ are included in other)
notes wbhom: Not available 1990

/* education */

gen byte ed=. /* under 3 years old */

if `year'==1980 {
replace ed=1 if 0<=grade & grade<=13 /* LTHS */
replace ed=1 if grade==14 /* 12th grade */ & fingrade~=2 /* didn't finish */
replace ed=2 if grade==14 & fingrade==2 /* finished */ /* HS */
replace ed=3 if 15<=grade & grade<=17 /* Some college */
replace ed=3 if grade==18 /* fourth year */ & fingrade~=2 /* didn't finish */
replace ed=4 if grade==18 & fingrade==2 /* finished */ /* college */
replace ed=5 if 19<=grade & grade<=22 /* advanced */
replace ed=. if 0<=age & age<=3
}
if `year'==1990 {
replace ed=1 if 1<=yearsch & yearsch<=9
/* LTHS: no school completed; nursery school; kindergarten; 1st, 2nd, 
3rd, or 4th grade; 5th, 6th, 7th, or 8th grade; 9th grade; 10th grade; 
11th grade; 12th grade, no diploma */
replace ed=2 if yearsch==10 /* high school graduate, diploma or GED */
replace ed=3 if 11<=yearsch & yearsch<=13
/* some college, but no degree; associate degree in college, occupational
program; associate degree in college, academic program */
replace ed=4 if yearsch==14 /* bachelor's degree */
replace ed=5 if 15<=yearsch & yearsch<=17
/* master's degree; professional degree; doctorate degree */
}
if `year'==2000 {
replace ed=1 if 1<=educ & educ<=8
/* no schooling completed; nursery school to 4th grade; 5th grade or
6th grade; 7th grade or 8th grade; 9th grade; 10th grade; 11th grade; 
12th grade, no diploma */
replace ed=2 if educ==9 /* high school graduate */
replace ed=3 if 10<=educ & educ <=12
/* some college, but less than 1 year; one or more years of college, no 
degree; associate degree */
replace ed=4 if educ==13 /* bachelor's degree */
replace ed=5 if 14<=educ & educ<=16
/* master's degree; professional degree; doctorate degree */
}
lab var ed "Education"
#delimit ;
lab def ed
1 "LTHS"
2 "HS"
3 "Some college"
4 "College"
5 "Advanced";
#delimit cr
lab val ed ed
notes ed: Missing if under 3 years old

	/* education: separating out primary school */

gen byte ed2=. /* under 3 years old */

if `year'==1980 {
replace ed2=1 if 0<=grade & grade<=10 /* primary only */
replace ed2=2 if 11<=grade & grade<=13 /* LTHS */
replace ed2=2 if grade==14 /* 12th grade */ & fingrade~=2 /* didn't finish */
replace ed2=3 if grade==14 & fingrade==2 /* finished */ /* HS */
replace ed2=4 if 15<=grade & grade<=17 /* Some college */
replace ed2=4 if grade==18 /* fourth year */ & fingrade~=2 /* didn't finish */
replace ed2=5 if grade==18 & fingrade==2 /* finished */ /* college */
replace ed2=6 if 19<=grade & grade<=22 /* advanced */
replace ed2=. if 0<=age & age<=3
}
if `year'==1990 {
replace ed2=1 if 1<=yearsch & yearsch<=5
/* primary or less: no school completed; nursery school; kindergarten; 1st, 2nd, 
3rd, or 4th grade; 5th, 6th, 7th, or 8th grade */
replace ed2=2 if 6<=yearsch & yearsch<=9
/* LTHS: 9th grade; 10th grade; 11th grade; 12th grade, no diploma */
replace ed2=3 if yearsch==10 /* high school graduate, diploma or GED */
replace ed2=4 if 11<=yearsch & yearsch<=13
/* some college, but no degree; associate degree in college, occupational
program; associate degree in college, academic program */
replace ed2=5 if yearsch==14 /* bachelor's degree */
replace ed2=6 if 15<=yearsch & yearsch<=17
/* master's degree; professional degree; doctorate degree */
}
if `year'==2000 {
replace ed2=1 if 1<=educ & educ<=4
/* no schooling completed; nursery school to 4th grade; 5th grade or
6th grade; 7th grade or 8th grade */
replace ed2=2 if 5<=educ & educ<=8
/* 9th grade; 10th grade; 11th grade; 12th grade, no diploma */
replace ed2=3 if educ==9 /* high school graduate */
replace ed2=4 if 10<=educ & educ <=12
/* some college, but less than 1 year; one or more years of college, no 
degree; associate degree */
replace ed2=5 if educ==13 /* bachelor's degree */
replace ed2=6 if 14<=educ & educ<=16
/* master’s degree; professional degree; doctorate degree */
}
lab var ed2 "Education, CEPAL"
#delimit ;
lab def ed2
1 "Primary, or less"
2 "LTHS"
3 "HS"
4 "Some college"
5 "College"
6 "Advanced degree";
#delimit cr
lab val ed2 ed2
notes ed2: Missing if under 3 years old
notes ed2: Separates out primary and less from the rest of LTHS

/* marital status */

if `year'==1980 | `year'==1990 {
gen byte marstat=.
replace marstat=1 if marital==0 /* now married, except separated */
replace marstat=2 if marital==1 /* widowed */
replace marstat=3 if marital==2 /* divorced */
replace marstat=4 if marital==3 /* separated */
replace marstat=5 if marital==4 /* never married or under 15 years old */
drop marital
}
if `year'==2000 {
* use variable marstat
}
lab var marstat "Marital status"
capture lab drop marstat
lab def marstat 1 Married 2 Widowed 3 Divorced 4 Separated 5 Single
lab val marstat marstat

/* disability */

gen byte empldis=. /* under 16 years old; all in 1980, 1990 */
if `year'==1980 | `year'==1990 {
* not available; see note below
}
if `year'==2000 {
replace empldis=1 if abwork==1 /* check original coding here */
replace empldis=0 if abwork==2
}
lab var empldis "Disability prevents work"
notes empldis: Missing in 1990
notes empldis: Based on abwork in 2000; missing if under 16 years old

/* 1990 and 2000 disability questions on PUMS 1% not compatible:

From US Census Bureau, Public Use Microdata Sample 2000: Technical 
Documentation, May 2003, p. B-8:

"Comparability. The 1990 census data products did not include a general 
disability status indicator. Furthermore, a comparable indicator could not
be constructed since the conceptual framework of the 1990 census was more
limited. The questionnaire included only three types of disability in 
questions with four subparts. The questions asked about whether an individual 
had a condition that had lasted for 6 months or more and that (1) limited the 
kind or amount of work that he or she could do at a job, (2) prevented the 
individual from working at a job, (3) made it difficult to go outside the
home alone (for example, to shop or visit a doctor's office), and (4) made it
difficult to take care of his or her own personal needs, such as bathing, 
dressing, or getting around inside the home. The 1990 disability questions 
were asked on the long form questionnaire of the population 15 years old and 
over."
*/

/* speak language other than English at home */

gen byte othlang=. /* missing if person less than than 5 years old */

if `year'==1980 | `year'==1990 {
replace othlang=0 if lang1==2
replace othlang=1 if lang1==1
drop lang1
}
if `year'==2000 {
replace othlang=0 if speak==2
replace othlang=1 if speak==1
drop speak
}
lab var othlang "Other language at home"
notes othlang: Missing if person is under 5 years old

/* ability to speak English */

if `year'==1980 | `year'==1990 {
replace english=. if english==0
}
if `year'==2000 {
rename engabil english
replace english=. if english==0 /* check coding */
}
capture lab drop english
lab var english "Speaks English"
lab def english 1 "Very well" 2 Well 3 "Not well" 4 "Not at all"
lab val english english
notes english: Missing if person is less than 5 years old, 1990, 2000, and if /*
*/ less than 3 in 1980

/* place of birth */

gen int pob1980=.
gen int pob1990=.
gen int pob2000=.

if `year'==1980 {
replace pob1980=birthpl
}
if `year'==1990 {
replace pob1990=pob
}
if `year'==2000 {
replace pob2000=pob1
}
do $do/17th_pums_poblabels.do /* adds correct labels for each year */
lab var pob1980 "Place of birth"
lab val pob1980 pob1980
lab var pob1990 "Place of birth"
lab val pob1990 pob
lab var pob2000 "Place of birth"
lab val pob2000 pob
notes pob1980: Not consistent with pob1990, pob2000
notes pob1990: Not consistent with pob1980; consistent with pob2000
notes pob2000: Not consistent with pob1980; consistent with pob1990

/* foreign born */

gen byte forborn=.

if `year'==1980 {
replace forborn=0 if 1<=birthpl & birthpl<=56 /* US states & DC */
replace forborn=0 if 60<=birthpl & birthpl<=81 /* Puerto Rico; US outlying */
replace forborn=1 if 110<=birthpl & birthpl<=997 /* foreign country; at sea */
}
if `year'==1990 {
replace forborn=0 if 1<=pob & pob<=56 /* US states & DC */
replace forborn=0 if 60<=pob & pob<=99 /* Puerto Rico; US outlying area */
replace forborn=1 if 100<=pob & pob<=555 
/* foreign country; at sea; abroad, not specified */
}
if `year'==2000 {
replace forborn=0 if 1<=pob1 & pob1<=56 /* US states & DC */
replace forborn=0 if 60<=pob1 & pob1<=96 /* island areas */
replace forborn=1 if 100<=pob1 & pob1<=554 /* foreign country or at sea */
}
lab var forborn "Foreign born"

/* place of birth */

gen byte mexico=0
gen byte elsalv=0
gen byte domrep=0
gen byte othlat=0
gen byte othfor=0

if `year'==1980 {
replace mexico=1 if birthpl==436
replace elsalv=1 if birthpl==433
replace domrep=1 if birthpl==477
replace othlat=1 if (400<=birthpl & birthpl<=477) & /*
*/ (mexico==0 & elsalv==0 & domrep==0)
replace othfor=1 if forborn==1 & (mexico==0 & elsalv==0 & domrep==0)
}
if `year'==1990 {
replace mexico=1 if pob==315
replace elsalv=1 if pob==312 
replace domrep=1 if pob==339
replace othlat=1 if (310<=pob & pob<=399) & /*
*/ (mexico==0 & elsalv==0 & domrep==0)
replace othfor=1 if forborn==1 & (mexico==0 & elsalv==0 & domrep==0)
}
if `year'==2000 {
replace mexico=1 if pob1==303
replace elsalv=1 if pob1==312 
replace domrep=1 if pob1==329
replace othlat=1 if (303<=pob1 & pob1<=399) & /*
*/ (mexico==0 & elsalv==0 & domrep==0)
replace othfor=1 if forborn==1 & (mexico==0 & elsalv==0 & domrep==0)
}
lab var mexico "Mexican"
lab var elsalv "Salvadoran"
lab var domrep "Dominican"
lab var othlat "Other Latin American"
lab var othfor "Other foreign born"

notes othlat: Includes all Latin American and Caribbean countries except /*
*/ Mexico, El Salvador, and Dominican Republic

/* year of arrival in United States */

gen byte arrived=.

if `year'==1980 {
replace arrived=1 if immigr==6				/* before 1950 */
replace arrived=2 if immigr==5				/* 1950-59 */
replace arrived=3 if immigr==4				/* 1960-64 */
replace arrived=4 if immigr==3				/* 1965-69 */
replace arrived=5 if immigr==2				/* 1970-74 */
replace arrived=6 if immigr==1				/* 1975-80 */
}
if `year'==1990 {
replace arrived=1 if immigr==10 				/* before 1950 */
replace arrived=2 if immigr==9 				/* 1950-59 */
replace arrived=3 if immigr==8 				/* 1960-64 */
replace arrived=4 if immigr==7 				/* 1965-69 */
replace arrived=5 if immigr==6 				/* 1970-74 */
replace arrived=6 if immigr==5 				/* 1975-79 */
replace arrived=7 if immigr==4 | immigr==3 		/* 1980-84 */
replace arrived=8 if immigr==2 | immigr==1      	/* 1985-90 */
replace arrived=. if immigr==0
}
if `year'==2000 {
replace arrived=1 if yr2us<1950				/* before 1950 */
replace arrived=2 if 1950<=yr2us & yr2us<=1959 	/* 1950-59 */  
replace arrived=3 if 1960<=yr2us & yr2us<=1964 	/* 1960-64 */
replace arrived=4 if 1965<=yr2us & yr2us<=1969 	/* 1965-69 */
replace arrived=5 if 1970<=yr2us & yr2us<=1974 	/* 1970-74 */
replace arrived=6 if 1975<=yr2us & yr2us<=1979 	/* 1975-79 */
replace arrived=7 if 1980<=yr2us & yr2us<=1984 	/* 1980-84 */
replace arrived=8 if 1985<=yr2us & yr2us<=1989 	/* 1985-89 */
replace arrived=9 if 1990<=yr2us & yr2us<=1994  	/* 1990-94 */
replace arrived=10 if 1995<=yr2us & yr2us<=2000  	/* 1995-2000 */
replace arrived=. if yr2us==0
}
lab var arrived "Year arrived in US"
#delimit ;
lab def arrived
1 "Before 1950"
2 "1950-1959"
3 "1960-1964"
4 "1965-1969"
5 "1970-1974"
6 "1975-1979"
7 "1980-1984"
8 "1985-1990"
9 "1991-1995"
10 "1996-2000";
#delimit cr
lab val arrived arrived

/* US citizenship */

if `year'==1980 {
rename citizen citstat
gen byte citizen=0
replace citizen=1 if citstat==0 | citstat==1 | citstat==3
}
if `year'==1990 {
rename citizen citstat
gen byte citizen=0
replace citizen=1 if 0<=citstat & citstat<=3
}
if `year'==2000 {
rename ctz citstat
gen byte citizen=0
replace citizen=1 if 1<=citstat & citstat<=4
}
lab var citizen "US citizen"

/* naturalized */

gen byte natized=0

if `year'==1980 {
replace natized=1 if citstat==1
}
if `year'==1990 {
replace natized=1 if citstat==3
drop citstat
}
if `year'==2000 {
replace natized=1 if citstat==4
drop citstat
}
lab var natized "Naturalized citizen"

/* labor force status */

gen byte lfs=. /* missing if under 16 years old */

if `year'==1980 {
replace lfs=1 if labor==1  /* civilian labor force: at work */ | /*
*/ labor==2 /* civilian: with a job but not at work */
replace lfs=2 if labor==3 /* unemployed */
replace lfs=3 if labor==6 /* not in labor force */
replace lfs=4 if labor==4 /* armed forces: at work */ | /*
*/ labor==5 /* armed forces: with a job but not at work */
}
if `year'==1990 {
replace lfs=1 if rlabor==1 | rlabor==2 
/* civilian employed, at work; civilian employed, with a job but not at work */
replace lfs=2 if rlabor==3 /* unemployed */
replace lfs=3 if rlabor==6 /* not in labor force */
replace lfs=4 if rlabor==4 | rlabor==5 
/* armed forces, at work; Armed forces, with a job but not at work */
}
if `year'==2000 {
replace lfs=1 if esr==1 | esr==2 
/* employed, at work; employed, with a job but not at work */
replace lfs=2 if esr==3 /* unemployed */
replace lfs=3 if esr==6 /* not in labor force */
replace lfs=4 if esr==4 | esr==5 
/* armed forces, at work; Armed forces, with a job but not at work */
}
lab var lfs "Labor force status"
lab def lfs 1 Employed 2 Unemployed 3 NILF 4 "Armed Forces"
lab val lfs lfs
notes lfs: Missing if under 16 years old

/* class of worker */

gen byte cow=.
gen byte cow1=.

if `year'==1980 {
	* cow
* cow not available in 1980
	* cow1
replace cow1=class
replace cow1=. if class==0
}
if `year'==1990 {
	* cow
replace cow=class
replace cow=. if class==0
/* less than 16 years old; unemployed who never worked; 
   NILF who last worked prior to 1985 */
replace cow=. if class==9
/* unemployed, last worked in 1984 or earlier */
	* cow1
replace cow1=1 if class==1 | class==2
replace cow1=2 if class==3
replace cow1=3 if class==4
replace cow1=4 if class==5
replace cow1=5 if class==6
replace cow1=6 if class==7
replace cow1=7 if class==8
}
if `year'==2000 {
	* cow
replace cow=clwkr
replace cow=. if clwkr==0
/* under 16 years old; last worked 1994 or earlier; or never worked */
replace cow=. if clwkr==9
/* unemployed, no work experience in the last 5 years */
	* cow1
replace cow1=1 if clwkr==1 | clwkr==2
replace cow1=2 if clwkr==3
replace cow1=3 if clwkr==4
replace cow1=4 if clwkr==5
replace cow1=5 if clwkr==6
replace cow1=6 if clwkr==7
replace cow1=7 if clwkr==8
}
lab var cow "Class of worker"
#delimit ;
lab def cow
1 "Employee, for-profit"
2 "Employee, non-profit"
3 "Employee, local govt"
4 "Employee, state govt"
5 "Employee, federal govt"
6 "Self-employed, uninc'd"
7 "Self-employed, inc'd"
8 "Unpaid family worker";
#delimit cr
lab val cow cow
lab var cow "Class of worker"
#delimit ;
lab def cow1
1 "Employee, private/non-profit"
2 "Employee, local govt"
3 "Employee, state govt"
4 "Employee, federal govt"
5 "Self-employed, uninc'd"
6 "Self-employed, inc'd"
7 "Unpaid family worker";
#delimit cr
lab val cow1 cow1
lab var cow1 "Class of worker"
notes cow: Includes some people not currently at work
notes cow1: Includes some people not currently at work
	
/* industry, detailed */

   /*
   1980 industry codes based on 1972 SIC codes
   1990 industry codes based on 1987 SIC codes
   2000 industry codes based on 1997 NAICS codes
   the three classification systems not matched in the following detailed 
   industry variables, but are comparable for aggregate industry variables
   */

gen byte ind1980=.
gen byte ind1990=.
gen byte ind2000=.

if `year'==1980 {
replace ind1980=industry
	/* experienced unemployed not classified by industry: */
replace ind1980=. if industry==991 /* last job Armed Forces */ | /*
*/ industry==992 /* last worked 1974 or earlier */
/* missing if: under 16 years of age; in Armed Forces; last worked before
1975 and not in labor force now; or never worked */
}
if `year'==1990 {
replace ind1990=industry
replace ind1990=. if industry==0 
/* less than 16 years old; unemployed who never worked; 
   NILF who last worked prior to 1985 */
}
if `year'==2000 {
replace ind2000=indcen
replace ind2000=. if indcen==0 
/* under 16 years old; last worked 1994 or earlier; or never worked */
}
lab var ind1980 "Industry, 1980"
notes ind1980: Not available in 1990, 2000
lab var ind1990 "Industry, 1990"
notes ind1990: Not available in 1980, 2000
lab var ind2000 "Industry, 2000"
notes ind2000: Not available in 1980, 1990

	/* manufacturing */
	
gen byte manuf=. /* less than 16 years old; unemployed who never worked; 
                    NILF who last worked five years or more ago */

if `year'==1980 {
replace manuf=0 if ind1980~=.
replace manuf=1 if 40<=industry & industry<=392
/* includes mining and construction */
}
if `year'==1990 {
replace manuf=0 if ind1990~=.
replace manuf=1 if 40<=industry & industry<=399
/* includes mining and construction */
}
if `year'==2000 {
replace manuf=0 if ind2000~=.
replace manuf=1 if 37<=indcen & indcen<=406
/* includes mining and construction */
}
lab var manuf "Manufacturing"
notes manuf: Includes mining and construction

	/* services */

gen byte servs=. /* less than 16 years old; unemployed who never worked; 
                    NILF who last worked prior to 1985 */

if `year'==1980 {
replace servs=0 if ind1980~=.
replace servs=1 if 400<=industry & industry<=932
/* includes transportation and communication */
}
if `year'==1990 {
replace servs=0 if ind1990~=.
replace servs=1 if 400<=industry & industry<=939
/* includes transportation and communication */
}
if `year'==2000 {
replace servs=0 if ind2000~=.
replace servs=1 if 407<=indcen & indcen<=966
/* includes transportation and communication */
}
lab var servs "Services"
notes servs: Includes transportation and communication

		/* retail trade */
		
gen byte retail=. /* less than 16 years old; unemployed who never worked; 
                    NILF who last worked prior to 1985 */

if `year'==1980 {
replace retail=0 if ind1980~=.
replace retail=1 if 580<=industry & industry<=691
}
if `year'==1990 {
replace retail=0 if ind1990~=.
replace retail=1 if 580<=industry & industry<=699
}
if `year'==2000 {
replace retail=0 if ind2000~=.
replace retail=1 if 467<=indcen & indcen<=606
}
lab var retail "Retail"

	/* agriculture */

gen byte agric=. /* less than 16 years old; unemployed who never worked; 
                    NILF who last worked prior to 1985 */

if `year'==1980 {
replace agric=0 if ind1980~=.
replace agric=1 if 10<=industry & industry<=31
/* includes forestry and fishing */
}
if `year'==1990 {
/* PUMS documentation apparently contradictory; file PUMSUSDD.TXT says that 
industry==0 corresponds to missing and that industry codes for agriculture 
begin at 10; file INDUSTRY.LST says that 0<=industry & industry<=10 cover 
"agricultural production, crops"; the PUMS data show no observations take 
codes 1-9; the following assumes that the PUMSUSDD.TXT file is correct */
replace agric=0 if industry~=0 & industry~=.
replace agric=1 if 10<=industry & industry<=39
/* includes forestry and fisheries */
}
if `year'==2000 {
replace agric=0 if indcen~=0 & indcen~=.
replace agric=1 if 1<=indcen & indcen<=36
/* includes forestry and fisheries */
}
lab var agric "Agriculture"
notes agric: Includes forestry and fisheries

	/* Armed Forces */

gen byte forces=. /* less than 16 years old; unemployed who never worked; 
                    NILF who last worked prior to 1985 */

if `year'==1980 {
* not available in 1980
}
if `year'==1990 {
replace forces=0 if industry~=0 & industry~=.
replace forces=1 if 940<=industry & industry<=991
/* active duty military */
}
if `year'==2000 {
replace forces=0 if indcen~=0 & indcen~=.
replace forces=1 if 967<=indcen & indcen<=987
/* active duty military */
}
lab var forces "Armed Forces"
notes forces: Active duty military

/* occupation, detailed */

   /* 
	1980 occupation codes based on 1980 Standard Occupational Classification
   	1990 occupation codes based on 1980 SOC
   	2000 occupation codes based on 2000 SOC
   	the two classification systems not matched in the following detailed 
   	occupation variables, but are comparable for aggregate occupation variables
   */

gen byte occ1980=.
gen byte occ1990=.
gen byte occ2000=.

if `year'==1980 {
replace occ1980=occup
replace occ1980=. if occup==0 
/* less than 16 years old; in Armed Forces; last worked before 1975 and not
in labor force; or never worked */
}
if `year'==1990 {
replace occ1990=occup
replace occ1990=. if occup==0 
/* less than 16 years old; unemployed who never worked; 
   NILF who last worked prior to 1985 */
}
if `year'==2000 {
replace occ2000=occcen1
replace occ2000=. if occcen1==0 
/* under 16 years old; last worked 1994 or earlier; or never worked */
}
lab var occ1980 "Occupation, 1980"
notes occ1980: Based on 1980 SOC; not identical to occ1990; not /*
*/ comparable to occ2000
lab var occ1990 "Occupation, 1990"
notes occ1990: Based on 1980 SOC; not identical to occ1980; not /*
*/ comparable to occ2000
lab var occ2000 "Industry, 2000"
notes occ2000: Based on 2000 SOC; not comparable to occ1980, occ1990

	/* manager or supervisor */

gen byte manager=. /* less than 16 years old; unemployed who never worked; 
   	  	            NILF who last worked prior to 1985 */

if `year'==1980 {
replace manager=0 if occ1980~=.
replace manager=1 if 3<=occup & occup<=19
/* Census code; description; 1980 SOC in parentheses
003 Legislators (111)
004 Chief executives and general administrators, public administration (112)
005 Administrators and officials, public administration (1132-1139)
006 Administrators, protective services (1131)
007 Financial managers (122)
008 Personnel and labor relations managers (123)
009 Purchasing managers (124)
013 Managers, marketing, advertising, and public relations (125)
014 Administrators, education and related fields (128)
015 Managers, medicine and health (131)
016 Managers, properties and real estate (1353)
017 Postmasters and mail superintendents (1344)
018 Funeral directors (part 1359)
019 Managers and administrators, n.e.c. (121, 126, 132-139 exc. 1344, 1353,
	part 1359)
*/
}
if `year'==1990 {
replace manager=0 if occ1990~=.
replace manager=1 if 3<=occup & occup<=22
/* Census code; description; 1980 SOC in parentheses
003 Legislators (111)
004 Chief executives and general administrators, public administration (112)
005 Administrators and officials, public administration (1132-1139)
006 Administrators, protective services (1131)
007 Financial managers (122)
008 Personnel and labor relations managers (123)
009-012 Purchasing managers (124)
013 Managers, marketing, advertising, and public relations (125)
014 Administrators, education and related fields (128)
015 Managers, medicine and health (131)
016 Postmasters and mail superintendents (1344)
017 Managers, food serving and lodging establishments (1351)
018 Managers, properties and real estate (1353)
019-020 Funeral directors (part 1359)
021 Managers, service organizations, n.e.c. (127, 1352, 1354, part 1359)
022 Managers and administrators, n.e.c. (121, 126, 132-1343, 136-139)
*/
}
if `year'==2000 {
replace manager=0 if occ2000~=.
replace manager=1 if 3<=occcen1 & occcen1<=22
/* Census code; description; 2000 SOC in parentheses
001-049 Management occupations: (11-0000)
001 Chief executives (11-1011)
002 General and operations managers (11-1021)
003 Legislators (11-1031)
004 Advertising and promotions managers (11-2011)
005 Marketing and sales managers (11-2020)
006 Public relations managers (11-2031)
007-009
010 Administrative services managers (11-3011)
011 Computer and Information Systems managers (11-3021)
012 Financial managers (11-3031)
013 Human resources managers (11-3040)
014 Industrial production managers (11-3051)
015 Purchasing managers (11-3061)
016 Transportation, storage, and distribution managers (11-3071)
017-019 Unused codes
020 Farm, ranch, and other agricultural managers (11-9011)
021 Farmers and Ranchers (11-9012)
022 Construction managers (11-9021)
023 Education administrators (11-9030)
024-029 Unused codes
030 Engineering managers (11-9041)
031 Food service managers (11-9051)
032 Funeral directors (11-9061)
033 Gaming managers (11-9071)
034 Lodging managers (11-9081)
035 Medical and health services managers (11-9111)
036 Natural sciences managers (11-9121)
037-039 Unused codes
040 Postmasters and mail superintendents (11-9131)
041 Property, real estate, and community association managers (11-9141)
042 Social and community service managers (11-9151)
043 Managers, all other (11-9199)
044-049 Unused codes
*/
}
lab var manager "Manager"
notes manager: Based on 1980 SOC in 1980, 1990; on 2000 SOC in 2000
notes manager: 1980 and 1990 not comparable with 2000

/* estimated hourly earnings in preceding year */

gen wage=.

if `year'==1980 {
replace wage=income1/(weeksw79*hours79) if (5<=income1 & income1<=75000) & /*
*/ (1<=weeksw79 & weeksw79<=52) & (1<=hours79 & hours79<=99)
replace wage=. if age<=15
}
if `year'==1990 {
replace wage=income1/(week89*hour89) if /*
*/ income1~=0 & week89~=0 & hour89~=0
replace wage=. if age<=15
}
if `year'==2000 {
replace wage=incws/(weeks*hours) if /*
*/ incws~=0 & weeks~=0 & hours~=0
}
lab var wage "Hourly wage, last year"
notes wage: Estimated hourly wage and salary earnings in preceding /*
*/ calendar year (current dollars)

/* weeks and hours worked last year */

gen byte weeksly=.
gen byte hoursly=.

if `year'==1980 {
	* weeks
replace weeksly=weeksw79
replace weeksly=. if age<=15 /* weeksw79 assigns zero instead of missing here */
	* hours
replace hoursly=hours79
replace hoursly=. if age<=15 /* hours79 assigns zero instead of missing here */
replace hoursly=. if weeksly==. /* otherwise appears as zero */
}
if `year'==1990 {
	* weeks
replace weeksly=week89
replace weeksly=. if age<=15 /* week89 assigns zero instead of missing here */
	* hours
replace hoursly=hour89
replace hoursly=. if age<=15 /* hour89 assigns zero instead of missing here */
replace hoursly=. if weeksly==.  /* otherwise appears as zero */
}
if `year'==2000 {
	* weeks
replace weeksly=weeks
replace weeksly=. if age<=16 /* weeks assigns zero instead of missing here */
	* hours
replace hoursly=hours
replace hoursly=. if age<=16 /* hours assigns zero instead of missing here */
replace hoursly=. if weeksly==. /* otherwise appears as zero */
}
lab var weeksly "Weeks worked last year"
notes weeksly: Missing if less than 15 in 1980, 1990; if less than 16 in 2000
lab var hoursly "Usual hours per week last year"
notes hoursly: Missing if less than 15 in 1980, 1990; if less than 16 in 2000
notes hoursly: Missing if didn't work last year

/* income in preceding calendar year */

	/* annual earnings from work in preceding year */
	
gen incwork=.

if `year'==1980 {
replace incwork=income1
replace incwork=. if age<=15
}	
if `year'== 1990 {
replace incwork=income1
replace incwork=. if age<=15
}
if `year'== 2000 {
replace incwork=incws
/* missing if 14 or under */
}
lab var incwork "Income from work, last year"
notes incwork: Annual income from work in preceding calendar year
notes incwork: Top-code in 1980: 75000; 1990: $140,000; in 2000, $175,000
notes incwork: Top-coded values assigned state-specific median above /*
*/ the topcode in 1990 and 2000
notes incwork: Missing if less than 15 in 1980, 1990; if less than 16 in 2000
	
	/* from self-employment farm and non-farm */

if `year'==1980 {
egen incself=rsum(income2 income3) /* farm and non-farm self-employment */ 
replace incself=. if age<=15
}
if `year'== 1990 {
egen incself=rsum(income2 income3) /* farm and non-farm self-employment */
replace incself=. if age<=15
}
if `year'== 2000 {
gen incself=incse  /* farm and non-farm self-employment */
replace incself=. if age<=14
}
lab var incself "Income self-employment, last year"
notes incself: Annual income from non-farm and farm self-employment in /*
*/ preceding calendar year
notes incself: Top-code in 1980: $75,000 (income2) and $75,000 (income3); in /*
*/ 1990: $90,000 (income2), $54,000 (income3); in 2000, $126,000
notes incself: Top-coded values assigned state-specific median above /*
*/ the topcode in 1990 and 2000
notes incself: Bottom-code in 1980: -$9,995; in 1990 and 2000: -$9,999
notes incself: Missing if less than 15 in 1980, 1990; if less than 14 in 2000

	/* from investments */

gen incinv=. /* interest, dividends, and net rental income */

if `year'==1980 {
replace incinv=income4
replace incinv=. if age<=14 /* missing if less than 15, not 16, as above */
}
if `year'== 1990 {
replace incinv=income4
replace incinv=. if age<=14 /* missing if less than 15, not 16, as above */
}
if `year'== 2000 {
replace incinv=incint
replace incinv=. if age<=14 
}
lab var incinv "Income investments, last year"
notes incinv: Annual income from interest, dividends, and net rental /*
*/ income in preceding calendar year
notes incinv: Top-code in 1980: 75000; in 1990: $40,000; in 2000, $50,000
notes incinv: Top-coded values assigned state-specific median above /*
*/ the topcode in 1990 and 2000
notes incinv: Bottom-code in 1980: $9,995; in 1990 and 2000: -$9,999

	/* from social security and SSI */

if `year'==1980 {
gen incsocl=income5
replace incsocl=. if age<=14
}
if `year'== 1990 {
gen incsocl=income5
replace incsocl=. if age<=14
}
if `year'== 2000 {
egen incsocl=rsum(incss incssi)
replace incsocl=. if age<=14
}
lab var incsocl "Income social security, last year"
notes incsocl: Annual income from social security including SSI /*
*/ in preceding calendar year
notes incsocl: Top-code in 1980: $9,995; in 1990: $17,000; in 2000, $18,000 /*
*/ (incss) and $13,800 (incssi)
notes incsocl: Top-coded values assigned state-specific median above /*
*/ the topcode in 1990 and 2000

	/* from public assistance or welfare */

gen incwelf=.

if `year'==1980 {
replace incwelf=income6
replace incwelf=. if age<=14
}
if `year'== 1990 {
replace incwelf=income6
replace incwelf=. if age<=14
}
if `year'== 2000 {
replace incwelf=incpa
replace incwelf=. if age<=14
}
lab var incwelf "Income welfare, last year"
notes incwelf: Annual income from welfare and public assistance /*
*/ in preceding calendar year
notes incwelf: Top-code in 1980: $9,995; in 1990: $10,000; in 2000: $12,300
notes incwelf: Topcoded values assigned state-specific median above /*
*/ the topcode in 1990 and 2000

	/* from pensions */

gen incpens=.

if `year'==1980 {
* not available in 1980
}
if `year'== 1990 {
replace incpens=income7
replace incpens=. if age<=14
}
if `year'== 2000 {
replace incpens=incret
replace incpens=. if age<=14
}
lab var incpens "Income pension, last year"
notes incpens: Annual income from pensions in preceding calendar year
notes incpens: Top-code in 1990: $30,000; in 2000, $52,000
notes incpens: Top-coded values assigned state-specific median above /*
*/ the topcode in 1990 and 2000
notes incpens: Not available in 1980

	/* from other sources */

if `year'==1980 {
gen incoth=income7
replace incoth=. if age<=14
}	
if `year'== 1990 {
gen incoth=income8
replace incoth=. if age<=14
}
if `year'== 2000 {
* use incoth
replace incoth=. if age<=14
}
lab var incoth "Income other sources, last year"
notes incoth: Annual income from other sources in preceding calendar year
notes incoth: Top-code in 1980: $75,000; in 1990: $20,000; in 2000: $37,800
notes incoth: Top-coded values assigned state-specific median above /*
*/ the topcode in 1990 and 2000
notes incoth: Includes pensions in 1980

	/* income from all sources */

if `year'==1980 {
gen inctot=income8
replace inctot=. if age<=14
}	
if `year'== 1990 {
gen inctot=rpincome
replace inctot=. if age<=14
}
if `year'== 2000 {
* use inctot
replace inctot=. if age<=14
}
lab var inctot "Income total, last year"
notes inctot: Annual income from all sources in preceding calendar year
notes inctot: Top-code in 1980: $75,000; in 1990: $401,000; in 2000: $5,000,000
notes inctot: Top-coded values assigned state-specific median above /*
*/ the topcode in 1990 and 2000
notes inctot: Bottom-code in 1980: -$9,995; in 1990: -$29,997; in 2000: -$19,998

/* live in same house as five years ago */

gen byte samehous=. /* missing if less than five years old */

if `year'==1980 {
replace samehous=0 if 1<=mig75 & mig75<=9
replace samehous=1 if mig75==1 /* same house */
}
if `year'==1990 {
replace samehous=0 if mobility==2
replace samehous=1 if mobility==1
}
if `year'==2000 {
replace samehous=0 if mob==2 | mob==3
/* no, outside the US; no, different house in the US */
replace samehous=1 if mob==1
}
lab var samehous "Same house as 5 years ago"
notes samehous: Confirm universe for 1980 variable

/* person's poverty status */

gen pov1=. 		/* banded poverty variable for consistency 1980-2000 */
gen byte poor=. 	/* 0-1 poverty variable */

if `year'==1980 {
	* 1980-2000 consistent, banded poverty variable
replace pov1=1 if poverty==1 /* <75% of poverty line */
replace pov1=2 if poverty==2 /* 75-99% */
replace pov1=3 if poverty==3 /* 100-124% */
replace pov1=4 if poverty==4 /* 125-149% */
replace pov1=5 if poverty==5 /* 150-174% */
replace pov1=6 if poverty==6 /* 175-199% */
replace pov1=7 if poverty==7 /* 200% + */
	* 1990-2000 consistent, continuous poverty variable
replace poverty=. /* not available in 1980 */
	* 1980-2000 consisent, 0-1 poverty variable
replace poor=0 if pov1~=.
replace poor=1 if pov1==1 | pov1==2
}
if `year'==1990 {
	* 1980-2000 consistent, banded poverty variable
replace pov1=1 if 1<=poverty & poverty<=74 /* <75% of poverty line */
replace pov1=2 if 75<=poverty & poverty<=99 /* 75-99% */
replace pov1=3 if 100<=poverty & poverty<=124 /* 100-124% */
replace pov1=4 if 125<=poverty & poverty<=149 /* 125-149% */
replace pov1=5 if 150<=poverty & poverty<=174 /* 150-174% */
replace pov1=6 if 175<=poverty & poverty<=199 /* 175-199% */
replace pov1=7 if 200<=poverty & poverty~=. /* 200% + */
	* 1990-2000 consistent, continuous poverty variable
replace poverty=. if poverty==0
	* 1980-2000 consisent, 0-1 poverty variable
replace poor=0 if pov1~=.
replace poor=1 if pov1==1 | pov1==2
}
if `year'==2000 {
	* 1980-2000 consistent, banded poverty variable
replace pov1=1 if 1<=poverty & poverty<=74 /* <75% of poverty line */
replace pov1=2 if 75<=poverty & poverty<=99 /* 75-99% */
replace pov1=3 if 100<=poverty & poverty<=124 /* 100-124% */
replace pov1=4 if 125<=poverty & poverty<=149 /* 125-149% */
replace pov1=5 if 150<=poverty & poverty<=174 /* 150-174% */
replace pov1=6 if 175<=poverty & poverty<=199 /* 175-199% */
replace pov1=7 if 200<=poverty & poverty~=. /* 200% + */
	* 1990-2000 consistent, continuous poverty variable
replace poverty=. if poverty==0
	* 1980-2000 consisent, 0-1 poverty variable
replace poor=0 if pov1~=.
replace poor=1 if pov1==1 | pov1==2
}
*
lab var pov1 "Person's income as share of poverty line"
lab define pov1 1 "<75%" 2 "75-99%" 3 "100-124%" 4 "125-149%" /*
*/ 5 "150-174%" 6 "175-199%" 7 "200% + "
lab val pov1 pov1
notes pov1: Banded variable available 1980-2000; continuous variable, /*
*/ poverty, available 1990-2000 only
notes pov1: Person's poverty status as determined by the Bureau /*
*/ the Census using official definition
notes pov1: Top-coded at 200% of poverty line
*
lab var poor "Poor"
*
lab var poverty "Person's income as share of poverty line"
notes poverty: Person's poverty status as determined by the Bureau /*
*/ the Census using official definition
notes poverty: Household income expressed as a percent of the poverty /*
*/ line corresponding to person's household
notes poverty: Top-coded at 500% of poverty line
notes poverty: Missing in 1980 if inmate of institution, person in /*
*/ military group quarters or in college dormitory, or unrelated individual /*
*/ under 15 years of age
notes poverty: Missing in 2000 if in institutional group quarters, in college /*
*/ dormitory or military quarters, or unrelated children under 15 years of age

/* travel-to-work */

if `year'==1980 {
gen byte travtime=.
replace travtime=time if 1<=time & time<=99
}
if `year'==1990 {
replace travtime=. if travtime==0
}
if `year'==2000 {
gen byte travtime=trvtime
replace travtime=99 if 100<=trvtime & trvtime<=120
replace travtime=. if trvtime==0
}
lab var travtime "Travel time to work (minutes)"
notes travtime: Top-coded in Census in 1980, 1990: 99 minutes; in 2000: /*
*/ 120 minutes; travtime variable here top-coded at 99 minutes in 1980, /*
*/ 1990, and 2000

/* commuting method */

gen byte pubtrans=.
gen byte bike=.
gen byte walk=.
gen byte workhome=.

if `year'==1980 {
	* public transportation
replace pubtrans=0 if 1<=means & means<=12
replace pubtrans=1 if 4<=means & means<=6 /* bus/streetcar, rail, subway/el */
	* bike
replace bike=0 if 1<=means & means<=12
replace bike=1 if means==9
	* walk
replace walk=0 if 1<=means & means<=12
replace walk=1 if means==10
	* work at home
replace workhome=0 if 1<=means & means<=12
replace workhome=1 if means==11
}
if `year'==1990 {
	* public transportation
replace pubtrans=0 if 1<=means & means<=12
replace pubtrans=1 if 2<=means & means<=6 /* bus etc., rail, subway, ferry */
	* bike
replace bike=0 if 1<=means & means<=12
replace bike=1 if means==9
	* walk
replace walk=0 if 1<=means & means<=12
replace walk=1 if means==10
	* work at home
replace workhome=0 if 1<=means & means<=12
replace workhome=1 if means==11
}
if `year'==2000 {
	* public transportation
replace pubtrans=0 if 1<=trvmns & trvmns<=12
replace pubtrans=1 if 2<=trvmns & trvmns<=6 /* bus etc., rail, subway, ferry */
	* bike
replace bike=0 if 1<=trvmns & trvmns<=12
replace bike=1 if trvmns==9
	* walk
replace walk=0 if 1<=trvmns & trvmns<=12
replace walk=1 if trvmns==10
	* work at home
replace workhome=0 if 1<=trvmns & trvmns<=12
replace workhome=1 if trvmns==11
}
lab var pubtrans "Commute on public transport"
lab var bike "Commute on bike"
lab var walk "Commute on foot"
lab var workhome "Work at home"

/* person weight */

if `year'==1980 {
gen perwgt=100 /* no weights in 1980 */
}
if `year'==1990 {
rename pwgt1 perwgt
}
if `year'==2000 {
rename pweight perwgt
}
lab var perwgt "Person weight"
notes perwgt: Equals pwgt1 in 1990; pweight in 2000

/* 
Copyright 2004 Sarah Gammage and John Schmitt

This program and all programs referenced in it are free software. You
can redistribute the program or modify it under the terms of the GNU
General Public License as published by the Free Software Foundation;
either version 2 of the License, or (at your option) any later version.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program; if not, write to the Free Software
Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307
USA.
*/